@echo off
Rem  
Rem  (c) tom-agplv3@jig.ch
Rem  Dieses Software untersteht der AGPLv3 Lizenz: https://choosealicense.com/licenses/agpl-3.0/
Rem   
Rem  Wichtig: Bitte beachte die Datei: Hinweis AGPLv3 Lizenz.txt
Rem   
Rem   
Rem Encoding: OEM 850
Rem 002, 200806, tom-agplv3@jig.ch
Rem 003, 201126, 
Rem 	PurgeNotifyObjects_exe
Rem 	Korrektur des Pfades. Danke, Flo!
Rem 	Das Resultat von PurgeNotifyObjects_exe wird 3s angezeigt
Rem 	Wenn PurgeNotifyObjects_exe fehlt, wird eine Warnung angezeigt

Echo.
Echo L”scht nach der Deinstallation von Cisco Anyconnect alle Leichen

SET "ScriptDir=%~dp0"
SET "PurgeNotifyObjects_exe=%ScriptDir%PurgeNotifyObjects.exe"



:checkPrivileges
NET FILE 1>NUL 2>NUL
if '%errorlevel%' == '0' ( goto gotPrivileges ) else ( goto getPrivileges )

:getPrivileges
if '%1'=='ELEV' (shift & goto gotPrivileges)
ECHO.
ECHO **************************************
ECHO Invoking UAC for Privilege Escalation
ECHO **************************************

setlocal DisableDelayedExpansion
set "batchPath=%~0"
setlocal EnableDelayedExpansion
ECHO Set UAC = CreateObject^("Shell.Application"^) > "%temp%\OEgetPrivileges.vbs"
ECHO UAC.ShellExecute "!batchPath!", "ELEV", "", "runas", 1 >> "%temp%\OEgetPrivileges.vbs"
"%temp%\OEgetPrivileges.vbs"
exit /B

:gotPrivileges
::::::::::::::::::::::::::::
::START
::::::::::::::::::::::::::::
setlocal & pushd .

REM Run as admin - put here code as you like

:: Den Neustart vorbereiten
Call :AddRunOnce

:: L”sche die Cisco-Leichen
"%PurgeNotifyObjects_exe%" -confirmdelete
If Exist "%PurgeNotifyObjects_exe%" (
	"%PurgeNotifyObjects_exe%" -confirmdelete
	Call :Sleep 3
) Else (
	Echo "Vorsicht!, PurgeNotifyObjects.exe nicht gefunden:"
	Echo "%PurgeNotifyObjects_exe%"
	Pause
)


Echo.
Echo Fertig.
Echo.
Goto :Reboot


:AddRunOnce
:: RunOnce: Explorer mit dem Onboarding-Script Dir öffnen
:: Den Parent-Folder des Scripts holen
For %%I in ("%~dp0.") do for %%J in ("%%~dpI.") Do Set "ParentFolder=%%~dpnxJ"
Set RegData="C:\Windows\explorer.exe \"%ParentFolder%\""
REG ADD HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnce /v "OpenOnboardingDir" /t REG_SZ /d %RegData% /f
Exit /b


:Sleep
:: Arg 1: Anzahl Sekunden schlafen
IF (%1)==() (
  SET sleep=1
) else (
  SET sleep=%1
)

FOR /L %%A IN (0,1,%sleep%) DO (
	Ping -w 1000 -n 1 1.1.0.0 > nul
	Echo|set /p=.
)
Echo.
Exit /b


:Reboot
Echo Reboot nicht sofort, damit das L”schen der Cisco-Leichen die Arbeit abschliessen kann
shutdown.exe /r /t 10
Exit /b


:Pause
Pause


:Ende
