@Echo off
Rem  
Rem  (c) tom-agplv3@jig.ch
Rem  Dieses Software untersteht der AGPLv3 Lizenz: https://choosealicense.com/licenses/agpl-3.0/
Rem   
Rem  Wichtig: Bitte beachte die Datei: Hinweis AGPLv3 Lizenz.txt
Rem   
Rem   
Rem 190301, tom-agplv3@jig.ch
Rem 200730, tom-agplv3@jig.ch
Rem 	Welcome-Msg
Rem 200806, tom-agplv3@jig.ch
Rem  WaitOnEndCmd mit Sleep
Rem  WaitOnEndPS mit Sleep


:: Konfiguration
SET WelcomeMsg=Baue die initiale Verbindung zu access.nosergroup.com auf

:: Verbose: 0 oder 1
SET Verbose=0
SET PowerShellVerbose=0
:: Ex: Call :Verbose "Verbose ist aktiv!"

:: WaitOnEnd: 
:: <Leer>  Nicht definiert
:: 0       Disabled, d.h. einfach schliessen
:: 1       Pause
:: >1      Sleep for n Seconds
SET WaitOnEndCmd=0
SET WaitOnEndPS=10


SET "ScriptDir=%~dp0"
SET "ScriptFilename=%~n0"
SET "PSScript_ps1=30 Create and install Certificate\30 Create Certificate.ps1"
:: Echo %PSScript_ps1%


:: Argumente, die dem PowerShell-Script mitgegeben werden
If (%WaitOnEndPS%)==() (
	SET "PSScript_Args="
) Else (
	SET "PSScript_Args=-WaitOnEnd %WaitOnEndPS%"
)


If NOT "%WelcomeMsg%"=="" (
	Echo.
	Echo %WelcomeMsg%
	Echo.
)


If Exist "%PSScript_ps1%" (
	Rem SET "PSScript=%ScriptDir%%PSScript_ps1%"
	Call :Verbose "PS1-Datei: gefunden"
	Call :StartPS "%PSScript_ps1%"
) Else (
	Call :Verbose "PS1-Datei: nicht gefunden"
)


If %WaitOnEndCmd% EQU 0 Goto :Ende
If %WaitOnEndCmd% EQU 1 Goto :Pause
Call :Sleep %WaitOnEndCmd%
Goto :Ende


:: =========================================================================

:StartPS
:: Startet eine ps1 - Datei
Rem Umgebende " entfernen
SET ScriptName=%~1
If (%Verbose%) == (1) (
	Echo Starte:
	Echo "%ScriptDir%%ScriptName%"
	Echo Args:
	Echo "%PSScript_Args%"
	Echo.
)

If (%PowerShellVerbose%) == (0) (
	PowerShell -ExecutionPolicy Bypass ". '%ScriptDir%%ScriptName%' %PSScript_Args%"
) Else (
	PowerShell -ExecutionPolicy Bypass ". '%ScriptDir%%ScriptName%' %PSScript_Args% -Verbose"
)
Exit /b


:Verbose
:: Wenn die Variable Verbose definiert ist, wird %1 ausgegeben
Rem Umgebende " entfernen
SET Message=%~1
Rem Doppelte " entfernen
SET Message=%Message:"=%
If (%Verbose%) == (1) Echo %Message%
Exit /b


:Sleep
:: Arg 1: Anzahl Sekunden schlafen
IF (%1)==() (
  SET sleep=1
) else (
  SET sleep=%1
)

FOR /L %%A IN (0,1,%sleep%) DO (
	Ping -w 1000 -n 1 1.1.0.0 > nul
	Echo|set /p=.
)
Echo.
Exit /b


:Pause
Echo.
Pause


:Ende
